Абстрактная фабрика на Delphi

Паттерны проектирования / Порождающие паттерны

type
  IProductA = interface
    function GetName: string;
  end;

  IProductB = interface
    function GetName: string;
  end;

  //abstract factory
  IFactory = interface
    function CreateA: IProductA;
    function CreateB: IProductB;
  end;

  TProductA1 = class(TInterfacedObject,
    IProductA)
    function GetName: string;
  end;

  TProductB1 = class(TInterfacedObject,
    IProductB)
    function GetName: string;
  end;

  //concrete factory 1
  TFactory1 = class(TInterfacedObject,
    IFactory)
    function CreateA: IProductA;
    function CreateB: IProductB;
  end;

function TProductA1.GetName: string;
begin
Result := 'ProductA1';
end;

function TProductB1.GetName: string;
begin
Result := 'ProductB1';
end;

function TFactory1.CreateA: IProductA;
begin
Result := TProductA1.Create;
end;

function TFactory1.CreateB: IProductB;
begin
Result := TProductB1.Create;
end;

//client works with any factory
procedure Run(const Factory: IFactory);
begin
  WriteLn(Factory.CreateA.GetName);
  WriteLn(Factory.CreateB.GetName);
end;

begin
  Run(TFactory1.Create);
  //ProductA1
  //ProductB1
end.

Предоставляет интерфейс для создания семейств объектов, интерфейсы которых известны, а конкретные классы нет.

Задача. Программа рисует окна в двух стилях, светлом и тёмном. Каждому стилю нужны своя кнопка и своё меню. Если код создаёт их напрямую, он может по ошибке соединить светлую кнопку с тёмным меню. А третий стиль заставит искать каждое место, где создаётся кнопка или меню.

Идея. Абстрактная фабрика - это интерфейс, в котором на каждый вид продукта есть свой метод создания. Каждая конкретная фабрика реализует его для одного семейства. Одна фабрика создаёт светлые кнопку и меню, другая - тёмные. Клиент получает фабрику и создаёт через неё все продукты. Конкретный продукт он никогда не называет, поэтому всё, что он получает, принадлежит одному семейству. Чтобы сменить семейство целиком, клиенту дают другую фабрику.

Как читать пример. Продукты бывают двух видов, A и B. Конкретная фабрика выпускает одно семейство: по одному продукту каждого вида, и у обоих один и тот же номер. Клиент получает фабрику, просит у неё по продукту каждого вида и пользуется обоими. Какое семейство ему досталось, клиент не знает, но вывод это показывает. В некоторых языках интерфейсов не объявляют вовсе, но роли остаются теми же.

Когда применять. Абстрактная фабрика нужна, когда продукты должны работать вместе и у них несколько семейств, как у тем оформления или операционных систем. При одном семействе она ни к чему. Не нужна она и тогда, когда продукты друг от друга не зависят: хватит конструктора или Фабричного метода.

Частая ошибка. Взять этот паттерн, пока виды продуктов ещё часто меняются. Каждый новый вид добавляет метод и в абстрактную фабрику, и в каждую конкретную.